proc membrane() {

	/* membrane defaults */
celsius		= 15
v_init		= -70		/* initial voltage; v at rest */
g_passive	= .0003		/* the standard pas conductance */
erev_passive	= -70		/* the pas reversal potential */
global_ra	= 125		/* the axial resistance */
set_ra()
gnaHH		= .12		/* standard HH gna */
gkHH		= .036		/*  standard HH gk  */
glHH		= .0003		/*  standard HH gl */


	/* Conductance coefficients for various sections */
	/* gfhillock = tapered from gfsoma to gfaxon */
gfsoma		= .5		/*0.5* standard HH conductances */
gfhill		= 2		/* 2* standard HH conductances */
gfaxon		= 4	
gfnode		= 10	
gfdend		= 0

	/* MEMBRANE */
	soma      {  insert hh  
		gnabar_hh= gfsoma*gnaHH 
		gkbar_hh= gfsoma*gkHH 
		gl_hh= gfsoma*glHH }
	hillock   {  insert hh
		gnabar_hh(0:1) = gfhill*gnaHH:gfsoma*gnaHH
		gkbar_hh(0:1) = gfhill*gkHH:gfsoma*gkHH
		gl_hh(0:1) = gfhill*glHH:gfsoma*glHH
	}
	axon	{
		insert hh	/* with tapering density */
		gnabar_hh(0:1) = gfaxon*gnaHH:gfhill*gnaHH
		gkbar_hh(0:1) = gfaxon*gkHH:gfhill*gkHH
		gl_hh(0:1) = gfaxon*glHH:gfhill*glHH
	}

	for i=0,nmyelin-1 {
		/* check whether g_pas.myelin should = g_passive/200 */
		myelin[i] { insert pas  g_pas= .003/200 e_pas= v_init cm= .005}
		node[i]   { insert hh  gnabar_hh= gfnode*gnaHH 
				gkbar_hh= gfnode*gkHH gl_hh= gfnode*glHH }
	}

	for i=0,ndend-1 {
		dend[i]  { insert pas  g_pas= g_passive  e_pas= erev_passive }
	}

	finitialize(v_init)
	fcurrent()
	forall {
		if (ismembrane("hh")) { el_hh= v + (ina +ik)/gl_hh }
	}
}